28. 多項式: 梯段函數

式子 */ x + s * i. n 一般稱為階乘函數 ,但為了避免與 「!」 函數弄混,吾人稱之為梯段函數;其定義的各因子間的差異為階差 s, 如梯段採礦的階梯。 梯段函數在精算作業與差分方程很有用。

階段方程為乘冪 ^ (在s=:0的案例為相等)的變形,由 合身連接詞 在其變異 ^!.s提供。 例如:
   x + s * i. n  [ x=: 7 [ n=: 5 [ s=: _1
7 6 5 4 3

   (*/x + s * i. n);(x ^!.s n);(x ^!.0 n);(x^n)
+----+----+-----+-----+
|2520|2520|16807|16807|
+----+----+-----+-----+
片語 +/c * x^!.s i.#c 稱為梯段多項式,如同 +/c*x^i.#c 被稱為乘冪多項式。 吾人定義副詞 P 為應用於任意階差 s 以提供相對應的梯段多項式:
   P=: 1 : '+/@([ * ] ^!. x. i.@#@[)"1 0'
   c=: 1 3 3 1 [ d=: 1 7 6 1 [ x=: 0 1 2 3 4
   (c p. x);(c 0 P x);(d _1 P x);(d p.!._1 x)
+-------------+-------------+-------------+-------------+
|1 8 27 64 125|1 8 27 64 125|1 8 27 64 125|1 8 27 64 125|
+-------------+-------------+-------------+-------------+
如前例所示,梯段多項式同等於 (適當選擇係數)普通多項式。兩者間的轉換以如下之矩陣乘積:
   VM=: 1 : '[ ^!.x./ i.@#@]'
   TO=: 2 : '(x. VM %. y. VM)~ @i.@#'
   (0 TO _1 c) +/ . * c
1 7 6 1
矩陣 0 TO _1 and _1 TO 0 為相互可逆,且與Stirling數有關:
   (0 TO _1 i.5);(_1 TO 0 i.5)
+---------+------------+
|1 0 0 0 0|1 0  0  0  0|
|0 1 1 1 1|0 1 _1  2 _6|
|0 0 1 3 7|0 0  1 _3 11|
|0 0 0 1 6|0 0  0  1 _6|
|0 0 0 0 1|0 0  0  0  1|
+---------+------------+
梯段多項式也可由 p.!.s 得到。


下個前個字彙索引主選單